// NW outdoor section.
// 0,0
beginoutdoorscript;

variables;
short choice;

body;

beginstate INIT_STATE;
// This state called whenever this section is loaded into memory.
break;

beginstate START_STATE;
// Starting state of the section, called every turn the party 
// stands inside this section until you change the state.
break;

beginstate 10;
	block_entry(1);
	message_dialog("This mountain path leads deeper into the Jszoula mountains. Nothing inhabits these areas, and this path will not bring you back to Solaria. You are better off searching elsewhere, and wisely turn back.","");
break;

beginstate 11;

if(get_flag(200,20) == 0)
{	reset_dialog();
	add_dialog_str(0,"You come across the largest farm you've seen in all of Keilan Province. There are acres of terraced fields, and even guard towers amongst the laborer's village and manor house.",0);
	add_dialog_str(1,"The lord of the manor is more than happy to speak with you and answer your questions about the golems. _Yes, we have seen troops of golems in the distance. They have never actually attacked us, they always maintain their distance._",0);
	add_dialog_str(2,"You ask him about the lands to the north. _My farm is on the edge of civilization, the lands to the northwest are a wilderness, barren of any humans until you get out of the Jszoula Mountains._",0);
	add_dialog_str(3,"_The lands are rugged and dangerous, not only because of the terrain, but also due to its unfriendly inhabitants. We rely on our guardposts for protection from bandits and wandering monsters._",0);
	add_dialog_choice(0,"Thank you.");
	run_dialog(1);
	set_flag(200,20,1);
}
	else print_str_color("The lord of the manor greets you.",2);
break;

beginstate 12;
if(get_flag(200,0) == 0)
	set_state_continue(13);
if(get_flag(200,0) == 1)
	end();
if(get_flag(200,0) == 2)
	if(get_flag(250,7) == 0)
	{	message_dialog("You meet with the giant chief again.","The chief explains that the giants have fled from the south due to the golems. The chief warns that the golems are a dreadful foe, who have decimated his tribe. You take your leave of him to continue your quest.");
		end(); }
	if(get_flag(250,7) > 0)
	{	message_dialog("You tell the giant chief of your victory over the golems. He smashes himself in the head with his club, a giant sign of respect; then looks confused when you don't do the same.","He soon forgets the slight, and orders his tribe to gather their gear and head south. Despite the difference in cultures, this has been a productive encounter.");
		reward_give(234);
		set_flag(200,0,1); }
break;

beginstate 13;
	reset_dialog();
	add_dialog_str(0,"You approached this camp with great caution, the totems and trophies decorating the entrance warn you that this camp's residents might not be friendly.",0);
	add_dialog_str(1,"You come over the crest of the hill and get your first glimpse of the camp's residents, a tribe of giants. They have already spotted you, but no boulders have crashed down on your heads as of yet. Perhaps you could talk your way out of a fight.",0);
	add_dialog_choice(0,"Attack them.");
	add_dialog_choice(1,"Approach them.");
	add_dialog_choice(2,"Leave.");
	choice = run_dialog(1);
	if(choice == 1)
	{	message_dialog("The giants unleash a barrage of boulders upon you. You charge up the hill to meet them.","");
		create_out_spec_enc(0); }
	if(choice == 2)
		if(get_flag(250,7) == 0)
		{	message_dialog("The giants seem relieved that you aren't attacking. When you reach their camp, one of them comes out to meet with you. He is the largest and most decorated of the group, must be the chief.","The chief explains that the giants have fled from the south due to the golems. The chief warns that the golems are a dreadful foe, who have decimated his tribe. You take your leave of him to continue your quest.");
			block_entry(1);
			set_flag(200,0,2);
			end(); }
		if(get_flag(250,7) > 0) {
			message_dialog("You tell the giant chief of your victory over the golems. He smashes himself in the head with his club, a giant sign of respect; then looks confused when you don't do the same.","He soon forgets the slight, and orders his tribe to gather their gear and head south. Despite the difference in cultures, this has been a productive encounter.");
			reward_give(234);
			block_entry(1);
			set_flag(200,0,1);
			end(); }
	if(choice == 3)
	{	block_entry(1);
		message_dialog("The giants lower their clubs and rocks as you retreat. At least no blood will be shed.","");
		end(); }
break;

beginstate 14;
	set_flag(200,0,1);
break;

beginstate 15;
	message_dialog("You dig through the giants gear and don't find much. The only thing of interest is a flask on the chieftain's hip.","");
	reward_give(234);
break;

beginstate 16;
	message_dialog("Somehow a group of golem scouts snuck up on you. Usually these creatures are slow and easy to avoid, but they have gotten so close to you that you are forced to fight.","");
break;

		
	